spitzer.f90

Go to the documentation of this file.

MODULE spitzer

CONTAINS
!-------------------------------------------------------!
!-------------------------------------------------------!

  SUBROUTINE spitzer_resistivity    (COREPROFILES, CORETRANSPORT) 

!-------------------------------------------------------!
!     This routine is used by the ETS workflow          !
!     to calculate Spitzer resistivity                  !
!-------------------------------------------------------!
!     Source:       ---                                 !
!     Developers:   D.Kalupin                           !
!     Kontacts:     Denis.Kalupin@euro-fusion.org       !
!                                                       !
!     Comments:     output CORE_TRANSPORT IDS is        !
!                   allocated inside the module         !
!                                                       !
!-------------------------------------------------------!

    USE ids_schemas
    USE ids_routines
    USE imas_constants_module
    USE allocate_working_ids
    USE ets_plasma
    USE get_composition
      

    IMPLICIT NONE

    INTEGER                             :: ifail

! +++ CPO types:
    TYPE (ids_core_profiles)            :: coreprofiles       !input IDS with profiles
    TYPE (ids_core_transport)           :: coretransport      !output IDS with transport (SIGMA)

! +++ ETS derived types:
    TYPE (plasma_composition)           :: composition


! +++ Dimensions:
    INTEGER (IDS_INT)                   :: ntime
    INTEGER (IDS_INT)                   :: nmod
    INTEGER (IDS_INT)                   :: nrho, irho


! +++ Internal variables:
    REAL   (IDS_REAL)                   :: clog               !Coulomb logarithm      
    REAL   (IDS_REAL),      ALLOCATABLE :: te(:)
    REAL   (IDS_REAL),      ALLOCATABLE :: ne(:)
    REAL   (IDS_REAL),      ALLOCATABLE :: tau_e(:)
    REAL   (IDS_REAL),      ALLOCATABLE :: sigma(:)

! +++ Constants:
      REAL (IDS_REAL),        PARAMETER :: me  = imas_constants%me*1e3_ids_real   !electron mass              [g]
      REAL (IDS_REAL),        PARAMETER :: e   = imas_constants%ev*3e9_ids_real   !elementary charge,         [esu]
      REAL (IDS_REAL),        PARAMETER :: cn  = 1.e-6_ids_real                   !density convergence        from [m^-3] to [cm^-3]
      REAL (IDS_REAL),        PARAMETER :: cs  = 9.e9_ids_real                    !conductivity convergence   from [(Ohm*m)^-1] to [s^-1]


! +++ Set dimensions:
      nrho                = SIZE(coreprofiles%profiles_1d(1)%grid%rho_tor_norm)
!      CALL GET_PROF_COMPOSITION (COREPROFILES, COMPOSITION)  !!! TRY EMPTY COMPOSITION

! +++ Allocate output CPO:
      ntime = 1
      nmod  = 1 
      CALL allocate_coretransport_ids(ntime, nmod, nrho, composition, coretransport)


      coretransport%ids_properties%comment(1)                           = "Spitzer resistivity"
      coretransport%ids_properties%source(1)                            = "spitzer_actor"
      coretransport%ids_properties%homogeneous_time                     = 1

      coretransport%model(1)%identifier%name(1)                         = "neoclassical"
      coretransport%model(1)%identifier%index                           = 5
      coretransport%model(1)%identifier%description(1)                  = "Spitzer resistivity"

      coretransport%model(1)%flux_multiplier                            = 0.0_ids_real

      CALL ids_copy(coreprofiles%profiles_1d(1)%grid, coretransport%model(1)%profiles_1d(1)%grid_d)
      CALL ids_copy(coreprofiles%profiles_1d(1)%grid, coretransport%model(1)%profiles_1d(1)%grid_v)
      CALL ids_copy(coreprofiles%profiles_1d(1)%grid, coretransport%model(1)%profiles_1d(1)%grid_flux)

!!$      CORETRANSPORT%model(1)%profiles_1d(1)%grid_d%rho_tor_norm         = COREPROFILES%profiles_1d(1)%grid%rho_tor_norm
!!$      CORETRANSPORT%model(1)%profiles_1d(1)%grid_d%rho_tor              = COREPROFILES%profiles_1d(1)%grid%rho_tor
!!$      CORETRANSPORT%model(1)%profiles_1d(1)%grid_d%psi                  = COREPROFILES%profiles_1d(1)%grid%psi
!!$      CORETRANSPORT%model(1)%profiles_1d(1)%grid_d%volume               = COREPROFILES%profiles_1d(1)%grid%volume
!!$      CORETRANSPORT%model(1)%profiles_1d(1)%grid_d%area                 = COREPROFILES%profiles_1d(1)%grid%area



! +++ Set up profiles:
      ALLOCATE (te(nrho))
      ALLOCATE (ne(nrho))
      ALLOCATE (tau_e(nrho))
      ALLOCATE (sigma(nrho))
      rho_loop1: DO irho =1,nrho
         te(irho)           = coreprofiles%profiles_1d(1)%electrons%temperature(irho)
         ne(irho)           = coreprofiles%profiles_1d(1)%electrons%density_thermal(irho)

 
! +++ Electron collisions:
!       determination of Coulomb logarithm:
         IF(te(irho).GE.10) clog = 24.e0_ids_real - 1.15e0_ids_real*log10(ne(irho)*cn) + 2.30e0_ids_real*log10(te(irho))
         IF(te(irho).LT.10) clog = 23.e0_ids_real - 1.15e0_ids_real*log10(ne(irho)*cn) + 3.45e0_ids_real*log10(te(irho))


!       electron collision time:
         tau_e(irho)          = (sqrt(2.d0*me)*(te(irho))**1.5) / 1.8d-19 / (ne(irho)*cn) / clog


!       Plasma electrical conductivity:
         sigma(irho)          = 1.96e0_ids_real * e**2 *ne(irho)*cn * tau_e(irho) /me /cs

      END DO rho_loop1

      coretransport%model(1)%profiles_1d(1)%conductivity_parallel = sigma

      IF (ALLOCATED(te))    DEALLOCATE (te)
      IF (ALLOCATED(ne))    DEALLOCATE (ne)
      IF (ALLOCATED(tau_e)) DEALLOCATE (tau_e)
      IF (ALLOCATED(sigma)) DEALLOCATE (sigma)

      RETURN

      END SUBROUTINE spitzer_resistivity    
!-------------------------------------------------------!
!-------------------------------------------------------!


END MODULE spitzer